#! /bin/csh -f

rm custom.mk

# set up $JSOC_MACHINE
set JSOC_MACHINE = `build/jsoc_machine.csh`
echo "Machine type is $JSOC_MACHINE"
echo ""

set CLEAN = "no"
set CHKLIBS = "no"
set CCMD = "c"
set LCMD = "l"
set LOCALIZE = "L"

foreach ARG ($argv)
    set FLAG = `echo $ARG | awk '{print substr($0, 2)}'`
    if ($FLAG == $CCMD) then
      set CLEAN = "yes"
    else if ($FLAG == $LCMD) then
      set CHKLIBS = "yes"
    endif
end

if ($CHKLIBS == "no") then
    echo -n "Remove links for local project configuration..."
    if (-d proj) then
	cd proj
	if (-e configure) then
	    rm configure
	endif
	if (-e make_basic.mk) then
	    rm make_basic.mk
	endif
	if (-e Rules.mk) then
	    rm Rules.mk
	endif
	if (-e target.mk) then
	    rm target.mk
	endif
	cd ..
    endif
    echo "done"

    echo -n "Remove links to man pages..."
    if (-e man) then
	rm -rf man
    endif
    echo "done"

    echo -n "Removing links to headers..."
    if (-d base/include) then
	cd base/include
	find . -name "*.h" -exec rm {} \;
	cd ../..
    endif

    if (-d include) then
	cd include
	find . -name "*.h" -exec rm {} \;
	cd ..
    endif
    echo "done"

    echo -n "Removing links to scripts..."
    if (-d scripts) then
	cd scripts
	find . -name "*" -exec rm {} \;
	cd ..
    endif
    echo "done"

    echo -n "Removing links to jsds..."
    if (-d jsds) then
	cd jsds
	find . -name "*" -exec rm {} \;
	cd ..
    endif
    echo "done"

    echo

    if ($CLEAN == "yes") then
	if (-x base/local/libs/dsds/scripts/rmlinks.csh) then
	    base/local/libs/dsds/scripts/rmlinks.csh
	endif

	if (-x base/local/libs/soi/scripts/rmlinks.csh) then
	    base/local/libs/soi/scripts/rmlinks.csh
	endif
    else
	echo -n "Setting links for local project configuration..."
	if (-e suflag.txt) then
	    cd proj
	    ln -sf ../projconf/su/configure configure
	    ln -sf ../projconf/su/make_basic.mk make_basic.mk
	    ln -sf ../projconf/su/Rules.mk Rules.mk
	    ln -sf ../projconf/su/target.mk target.mk
	    cd ..
	else
	    cd proj
	    ln -sf ../projconf/ex/configure configure
	    ln -sf ../projconf/ex/make_basic.mk make_basic.mk
	    ln -sf ../projconf/ex/Rules.mk Rules.mk
	    ln -sf ../projconf/ex/target.mk target.mk
	    cd ..
	endif
	echo "done"

	echo "Setting links to man pages..."
	if (-d /home/jsoc/man) then
	    if (!(-e man)) then
		ln -s /home/jsoc/man man
	    endif
	endif
	echo "done"

	echo "Setting links to headers..."
	if (!(-d base/include)) then
	    mkdir -p base/include
	endif
	cd base/include
	find .. -path '../include' -prune -o -name \*.h  \( \( -exec ln -s {} . \; -a -exec echo "  " {} " OK" \; \) -o -exec echo "  " {} " ERROR - couldn't create link" \; \)
	cd ../..

	if (!(-d include)) then
	    mkdir -p include
	endif
	cd include
	if (-d ../base/include) then
	    find ../base/include -name \*.h -exec ln -s {} . \;
	endif
	cd ..
	echo "done"
	echo
	
	echo "Setting links to scripts..."
        if (!(-d scripts)) then
	    mkdir scripts
	endif
	cd scripts

	# Sums scripts
	find ../base/sums/scripts -mindepth 1 \( -path \*CVS -prune -o -exec ln -s {} . \; -a -exec echo "  " {} " OK" \; \) -o -exec echo "  " {} " ERROR - couldn't create link" \;

	# Util scripts
	find ../base/util/scripts -mindepth 1 \( -path \*CVS -prune -o -exec ln -s {} . \; -a -exec echo "  " {} " OK" \; \) -o -exec echo "  " {} " ERROR - couldn't create link" \;

	# DRMS / IDL-interface scripts
	find ../base/drms/scripts -mindepth 1 \( -path \*CVS -prune -o -exec ln -s {} . \; -a -exec echo "  " {} " OK" \; \) -o -exec echo "  " {} " ERROR - couldn't create link" \;

	# Project-specific scripts - these won't show up if you don't have the project source.
	if (-x ../proj/configure) then
	    ../proj/configure
	endif

	cd ..
	echo "done"
	echo

	echo "Setting links to jsds..."
	if (!(-d jsds)) then
	    mkdir jsds
	endif
	cd jsds
	find ../base \( -name \*.jsd -exec ln -s {} . \; -a -exec echo "  " {} " OK" \; \) -o \( -name \*.jsd -exec echo "  " {} " ERROR - couldn't create link" \; \)
	cd ..
	echo "done"
	echo
       
        if (-e suflag.txt) then           
            # Stanford third-party libraries
            echo 'POSTGRES_LIB = pq' >> custom.mk
            echo 'CFITSIO_LIB = cfitsio' >> custom.mk

            echo 'ifeq (\$(JSOC_MACHINE), linux_x86_64)\n' >> custom.mk
            echo '  POSTGRES_INCS = /usr/include' >> custom.mk
            echo '  POSTGRES_LIBS = /usr/lib64' >> custom.mk
            echo '  CFITSIO_INCS = /home/jsoc/include' >> custom.mk
            echo '  CFITSIO_LIBS = /home/jsoc/lib/linux-x86_64' >> custom.mk
            echo 'endif' >> custom.mk

            echo 'ifeq (\$(JSOC_MACHINE), linux_ia32)\n' >> custom.mk
            echo '  POSTGRES_INCS = /usr/include' >> custom.mk
            echo '  POSTGRES_LIBS = /usr/lib' >> custom.mk
            echo '  CFITSIO_INCS = /home/jsoc/include' >> custom.mk
            echo '  CFITSIO_LIBS = /home/jsoc/lib/linux-ia32' >> custom.mk
            echo 'endif' >> custom.mk

            # Set custom make file to tell the make system that the gcc cfitsio library is called
            # libcfitsio_gcc.a
            echo 'ifeq ($(COMPILER), gcc)' >> custom.mk
            echo '  ifeq ($(JSOC_MACHINE), linux_x86_64)' >> custom.mk
            echo '    CFITSIO_LIB = cfitsio_gcc' >> custom.mk
            echo '  endif' >> custom.mk
            echo 'endif' >> custom.mk
        endif

        # Make customizations - ensure changes here are synchronized to changes in make_basic.mk
        if (!(-e suflag.txt)) then
            # put compilation customizations here
            # echo "DRMS_DEFAULT_RETENTION = -10" >> custom.mk
        endif

	echo "done"
	echo

	# generate links for DSDS/SOI dynamic libraries - only do this if 
	# user's environment has access to /home/soi/CM
	if (-d /home/soi/CM/include && -d /home/soi/CM/src) then
	    if (-x base/local/libs/dsds/scripts/genlinks.csh) then
		base/local/libs/dsds/scripts/genlinks.csh
	    endif

	    if (-x base/local/libs/soi/scripts/genlinks.csh) then
		base/local/libs/soi/scripts/genlinks.csh
	    endif
	endif
    endif
endif

# Enter required library names and versions here.
if ($CHKLIBS == "yes") then

endif 

# Site Localization
if (!(-e suflag.txt)) then
  if (!(-e config.local)) then
    echo "Error: config.local not found. If you have a saved version of this"
    echo "       file from a previous installation, you should copy that into"
    echo "       this directory and rerun configure. Otherwise, copy the file"
    echo "       config.local.template to config.local and edit the config.local"
    echo "       file to contain site-appropriate values."
    echo 
    echo "*** IMPORTANT *** The edited config.local will contain site-specific"
    echo "    values that should not be modified during subsequent updates to"
    echo "    NetDRMS. Keep a safe copy of it somewhere outside of the DRMS"
    echo "    directory tree, for example in /usr/local. After each NetDRMS"
    echo "    update, ensure this file is in place."
  else
    echo "CUSTOM_DEFINES = __LOCALIZED_DEFS__" >> custom.mk
    ./gen_init.csh
    ./customizemake.pl
  endif
else if (-e config.local)
    # config.local is optional at Stanford, but it won't necessarily contain the same information that 
    # a NetDRMS config.local contains. The first section contains items that will override the
    # the items in serverdefs.h. The second section contains items used to populate custom.mk, 
    # which causes make systems variables to be defined that override the default make behavior
    # (such as overriding the name of the directory to which binary data are written - linux_x86_64_n02
    # instead of linux_x86_64, for example).

    # Override the defaults defined in serverdefs.h (don't use gen_init.csh as it does several things, 
    # most of which are relevant only to non-SU NetDRMS sites). This script causes all 
    # items included in config.local to override those defined in serverdefs.h, but not all
    # items need be specified in config.local.
    ./customizedefs.pl
    echo "CUSTOM_DEFINES = __CUSTOMIZED_DEFS__" >> custom.mk

    # update custom.mk with data from config.local
    ./customizemake.pl
endif

# Customize compilers
# echo "JSOC_COMPILER = gcc" >> custom.mk
# echo "JSOC_FCOMPILER = gfortran" >> custom.mk

# run perl script to do even more configuration
./moreconfigure.pl -fcustom.mk