Return to doretilen CVS log

Up to [Development] / JSOC / proj / globalhs / scripts

generalize to use retnjobs

#! /bin/tcsh -f

setenv PATH $JSOCROOT/bin/$JSOC_MACHINE':'$JSOCROOT/proj/globalhs/scripts':'$PATH

# number of jobs will be ntimechunks = (totalsecs / chunksecs) rounded up
# or njobs, whichever is less

# submit njobs jobs at once
if (! $?GLOBALHS_RETNJOBS) then
  set njobs=6
else
  set njobs=$GLOBALHS_RETNJOBS
endif

# submit next batch of jobs when total number of retile jobs drops below jobthreshold
if (! $?GLOBALHS_RETJOBTHRESHOLD) then
  set jobthreshold=2
else
  set jobthreshold=$GLOBALHS_RETJOBTHRESHOLD
endif

# if this script inherited a label in its environment, use it as the suffix for job names
if (! $?GLOBALHS_LABEL) then
  set suff=''
else
  set suff=.$GLOBALHS_LABEL
endif

set qsubtmp=/tmp27/$USER/qsubtmp
mkdir -p $qsubtmp
if (! $?GLOBALHS_RETQUEUE) then
  set q=j.q
else
  set q=$GLOBALHS_RETQUEUE
endif

if ($q == a.q) then
  alias qsub qsub2
  alias qstat qstat2
  alias waittosubmit waittosubmit2
endif

@ i = 1
while ($i <= $#argv )
  set $argv[$i]
@ i++
end

if (! $?starttime) then
  echo must specify parameter starttime
  exit 1
endif

if (! $?totaltime) then
  echo must specify parameter totaltime
  exit 1
endif

if (! $?lchunkin) then
  echo must specify parameter lchunkin
  exit 1
endif

set totalsecs = `durcon $totaltime`
if ($status) then
  echo incorrect format for parameter totaltime
  exit 1
endif

if (! $?timechunk) set timechunk = 12d
set chunksecs = `durcon $timechunk`
if ($status) then
  echo incorrect format for parameter timechunk
  exit 1
endif

set ntimechunks = `echo "$totalsecs / $chunksecs" | bc`

if (! $?lmin) set lmin = 0
if (! $?lmax) set lmax = 300
if (! $?lchunkout) set lchunkout = $lchunkin

if (($lchunkin % $lchunkout && $lchunkin < $lmax + 1) && ($lchunkout % $lchunkin && $lchunkout < $lmax + 1)) then
  echo lchunkout must evenly divide lchunkin or lchunkin must evenly divide lchunkout
  exit 1
endif

date
echo $PWD
echo $0 $argv

if (! -es ret.parms.blank) then
  echo parameter file blank missing: ret.parms.blank is required
  exit 1
endif

grep -v "^[[:space:]]*#" ret.parms.blank | sed s@"[[:space:]]"@"\n"@g | grep -v '^[[:space:]]*$'  > parms.tmp

set in = `cat parms.tmp | grep ^in= | sed s/\'//g | sed s/\"//g | awk -F '[=[]' '{print $2}'`
set epoch = `show_info -j $in | grep -i '^keyword:t_start_epoch' | cut -d, -f5`
set epochsecs = `time_convert o=jsoc time=$epoch`
set tstartstep = `show_info -j $in | grep -i '^keyword:t_start_step' | cut -d, -f5`
# the following assumes t_start_step is given in seconds
set indexchunk = `echo "$chunksecs / $tstartstep" | bc`

durcon $starttime >& /dev/null
if ($status) then
  set startsecs = `time_convert o=jsoc time=$starttime`
else
  set startsecs = `durcon $starttime` 
  set startsecs = `echo "$startsecs + $epochsecs" | bc`
endif

set firstindex = `echo "($startsecs - $epochsecs)/$tstartstep" | bc`
set nextfirstindex = `echo "($startsecs + $totalsecs - $epochsecs)/$tstartstep" | bc`

@ lchunkfirst = $lmin / $lchunkin
@ lchunklast  = $lmax / $lchunkin
@ nlc = ($lchunklast - $lchunkfirst) + 1

# calculate first llast
@ lfirst = $lchunkfirst * $lchunkin 
@ llast  = $lfirst + $lchunkin - 1
if ($llast  > $lmax) set llast  = $lmax
#calculate last lfirst
@ lfirst = $lchunklast * $lchunkin
if ($lfirst < $lmin) set lfirst = $lmin
set tagclause = `cat parms.tmp | grep ^in= | cut -d= -f2- | sed s/"'"/""/g | sed s@"\["@"\n"@g | sed s@]@"\n"@g | grep TAG`
set ndt = `cat parms.tmp | grep ^in= | awk -F '[][]' '{print $8}'`
set inrecset = $in'['$starttime/$totaltime']['$lmin-$lfirst']['$llast-$lmax']['$ndt']['$tagclause']'
show_info -q "$inrecset" key=version >& version.tmp
set version = `uniq version.tmp`
if ($#version > 1) then
  echo VERSION varies across the input
  exit 1
endif

# limit desc 1024 used to be necessary, apparently now it isn't
set i=0
while ($i < $ntimechunks)
@ index = $firstindex + $i * $indexchunk
  set isecs = `echo "$startsecs + ($i * $chunksecs)" | bc`
  set istart = `time_convert o=cal zone=tai s=$isecs`
@ r = $i % $njobs
  set subfile = subr.$firstindex.$lmin-$lmax.$r$suff
  if ($i < $njobs) then
    echo '#\!/bin/csh' > $subfile
    echo 'setenv PATH' $JSOCROOT'/bin/$JSOC_MACHINE' >> $subfile
    echo 'cd' $PWD >> $subfile
  endif
  set interval = '#'$index'/'$indexchunk
@ lc = $lchunkfirst
  while ($lc <= $lchunklast)
  @ lfirst = $lc * $lchunkin 
  @ llast  = $lfirst + $lchunkin - 1
    if ($lfirst < $lmin) set lfirst = $lmin
    if ($llast  > $lmax) set llast  = $lmax
    cat parms.tmp | sed s@XXXX@$interval@g | sed s/MMMM/$llast/g | sed s/NNNN/$lfirst/g | sed s/CCCC/$lchunkout/g | sed s/TTTT/$timechunk/g | sed s/SSSS/$istart/g > ret.parms.$index.$lfirst-$llast
    echo \(time jretile @ret.parms.$index.$lfirst-$llast\) '>&' ret.log.$index.$lfirst-$llast >> $subfile
    echo echo \$status '>&' jretile.exitstatus.$index.$lfirst-$llast >> $subfile
  @ lc++
  end
@ i++
end

@ index += $indexchunk
if ($index < $nextfirstindex) then
@ indexchunk = $nextfirstindex - $index
  set isecs = `echo "$startsecs + ($i * $chunksecs)" | bc`
  set istart = `time_convert o=cal zone=tai s=$isecs`
  set chunksecs = `echo "$indexchunk * $tstartstep" | bc`
@ r = $i % $njobs
  set subfile = subr.$firstindex.$lmin-$lmax.$r$suff
  if ($i < $njobs) then
    echo '#\!/bin/csh' > $subfile
    echo 'setenv PATH' $JSOCROOT'/bin/$JSOC_MACHINE' >> $subfile
    echo 'cd' $PWD >> $subfile
  endif
  set interval = '#'$index'/'$indexchunk
@ lc = $lchunkfirst
  while ($lc <= $lchunklast)
  @ lfirst = $lc * $lchunkin 
  @ llast  = $lfirst + $lchunkin - 1
    if ($lfirst < $lmin) set lfirst = $lmin
    if ($llast  > $lmax) set llast  = $lmax
    cat parms.tmp | sed s@XXXX@$interval@g | sed s/MMMM/$llast/g | sed s/NNNN/$lfirst/g | sed s/CCCC/$lchunkout/g | sed s/TTTT/$chunksecs's'/g | sed s/SSSS/$istart/g > ret.parms.$index.$lfirst-$llast
    echo \(time jretile @ret.parms.$index.$lfirst-$llast\) '>&' ret.log.$index.$lfirst-$llast >> $subfile
    echo echo \$status '>&' jretile.exitstatus.$index.$lfirst-$llast >> $subfile
  @ lc++
  end
@ ntimechunks++
  set chunksecs = `durcon $timechunk`
  set indexchunk = `echo "$chunksecs / $tstartstep" | bc`
endif

if ($ntimechunks < $njobs) set njobs=$ntimechunks
echo $njobs job scripts created

waittosubmit $jobthreshold subr
set i=0
while ($i < $njobs)
  set subfile = subr.$firstindex.$lmin-$lmax.$i$suff
  qsub -q $q -e $qsubtmp -o $qsubtmp $subfile
@ i++
end

echo jobs submitted, start waiting

set njobsrunning = `qstat -r -u $USER | grep "Full jobname:" | grep subr.$firstindex | grep $lmin-$lmax | grep "$suff" | wc -l`
while($njobsrunning > 0)
  sleep 60
  set njobsrunning = `qstat -r -u $USER | grep "Full jobname:" | grep subr.$firstindex | grep $lmin-$lmax | grep "$suff" | wc -l`
end

#check for errors here

set expectedlist = `/bin/ls ret.parms.[0-9]* | cut -d'.' -f 3-4`
set ranlist      = `/bin/ls ret.log.*   | cut -d'.' -f 3-4`
set rerunlist = `echo $expectedlist $ranlist | sed s/" "/"\n"/g | sort -n | uniq -u`

set errlist1 = `grep -Hv 0 jretile.exitstatus.* | awk -F '[.:]' '{print $3"."$4}'`
set errlist2 = `grep -Hc "successful completion" ret.log.* | grep -v :1 | awk -F '[.:]' '{print $3"."$4}'`
set errlist = `echo $errlist1 $errlist2 | sed s/" "/"\n"/g | sort -n | uniq`

if ($#rerunlist || $#errlist) then
  echo some jobs fail, rerunning
  echo rerunlist: $rerunlist > faillog
  echo errlist1: $errlist1 >> faillog
  echo errlist2: $errlist2 >> faillog
# could create multiple qsub scripts, but failures of this script are so rare that i'm not bothering.
  set subfile = subr.$firstindex.redo.$lmin-$lmax$suff
  echo '#\!/bin/csh' > $subfile
  echo 'setenv PATH' $JSOCROOT'/bin/$JSOC_MACHINE' >> $subfile
  echo 'cd' $PWD >> $subfile
  foreach ind ($errlist $rerunlist)
# in this case ind is actually a composite of time index and l range
    echo \(time jretile @ret.parms.$ind\) '>&' ret.log.$ind >> $subfile
    echo echo \$status '>&' jretile.exitstatus.$ind >> $subfile
  end

  waittosubmit $jobthreshold subr
  qsub -q $q -e $qsubtmp -o $qsubtmp subr.$firstindex.redo.$lmin-$lmax$suff

  set njobsrunning = `qstat -r -u $USER | grep "Full jobname:" | grep subr.$firstindex | grep $lmin-$lmax | grep "$suff" | wc -l`
  while($njobsrunning > 0)
    sleep 60
    set njobsrunning = `qstat -r -u $USER | grep "Full jobname:" | grep subr.$firstindex | grep $lmin-$lmax | grep "$suff" | wc -l`
  end

  set ranlist   = `/bin/ls ret.log.*   | cut -d'.' -f 3-4`
  set rerunlist = `echo $expectedlist $ranlist | sed s/" "/"\n"/g | sort -n | uniq -u`
  set errlist1 = `grep -Hv 0 jretile.exitstatus.* | awk -F '[.:]' '{print $3"."$4}'`
  set errlist2 = `grep -Hc "successful completion" ret.log.* | grep -v :1 | awk -F '[.:]' '{print $3"."$4}'`

  if ($#errlist1 || $#errlist2 || $#rerunlist) then
    echo some jobs still fail, i give up
    exit 1
  endif
endif

echo successful completion

rm parms.tmp version.tmp

exit 0