Return to dosht CVS log

Up to [Development] / JSOC / proj / globalhs / scripts

added setting of PATH and checking of data VERSION to scripts

#!/bin/tcsh -f

setenv PATH $JSOCROOT/bin/$JSOC_MACHINE':'$JSOCROOT/proj/globalhs/scripts':'$PATH

# number of jobs will be ntimechunks = (totalsecs / chunksecs) rounded up

# submit next batch of jobs when total number of sht jobs drops below jobthreshold
if (! $?GLOBALHS_V2TJOBTHRESHOLD) then
  set jobthreshold=70
else
  set jobthreshold=$GLOBALHS_V2TJOBTHRESHOLD
endif

# if this script inherited a label in its environment, use it as the suffix for job names
if (! $?GLOBALHS_LABEL) then
  set suff=''
else
  set suff=.$GLOBALHS_LABEL
endif

set qsubtmp=/tmp27/$USER/qsubtmp
mkdir -p $qsubtmp
if (! $?GLOBALHS_V2TQUEUE) then
  set q=j.q
else
  set q=$GLOBALHS_V2TQUEUE
endif

if ($q == a.q) then
  alias qsub qsub2
  alias qstat qstat2
  alias waittosubmit waittosubmit2
endif

@ i = 1
while ($i <= $#argv )
  set $argv[$i]
@ i++
end

if (! $?starttime) then
  echo must specify parameter starttime
  exit 1
endif

if (! $?totaltime) then
  echo must specify parameter totaltime
  exit 1
endif

set totalsecs = `durcon $totaltime`
if ($status) then
  echo incorrect format for parameter totaltime
  exit 1
endif

if (! $?timechunk) set timechunk = 1d
set chunksecs = `durcon $timechunk`
if ($status) then
  echo incorrect format for parameter timechunk
  exit 1
endif

set ntimechunks = `echo "$totalsecs / $chunksecs" | bc`

if (! $?lmin) set lmin = 0
if (! $?lmax) set lmax = 300
if (! $?lchunk) set lchunk = 40

date
echo $PWD
echo $0 $argv

if (! -es v2t.parms.blank) then
  echo parameter file blank missing: v2t.parms.blank is required
  exit 1
endif

grep -v "^[[:space:]]*#" v2t.parms.blank | sed s@"[[:space:]]"@"\n"@g | grep -v '^[[:space:]]*$'  > parms.tmp

set in = `cat parms.tmp | grep ^in= | sed s/\'//g | sed s/\"//g | awk -F '[=[]' '{print $2}'`
set epoch = `show_info -j $in | grep -i '^keyword:t_rec_epoch' | cut -d, -f5`
set epochsecs = `time_convert o=jsoc time=$epoch`
set trecstep = `show_info -j $in | grep -i '^keyword:t_rec_step' | cut -d, -f5`
set indexchunk = `echo "$chunksecs / $trecstep" | bc`

durcon $starttime >& /dev/null
if ($status) then
  set startsecs = `time_convert o=jsoc time=$starttime`
else
  set startsecs = `durcon $starttime` 
  set startsecs = `echo "$startsecs + $epochsecs" | bc`
endif

set firstindex = `echo "($startsecs - $epochsecs)/$trecstep" | bc`
set nextfirstindex = `echo "($startsecs + $totalsecs - $epochsecs)/$trecstep" | bc`

set i=0
while ($i < $ntimechunks)
@ index = $firstindex + $i * $indexchunk
  set isecs = `echo "$startsecs + ($i * $chunksecs)" | bc`
  set istart = `time_convert o=cal zone=tai s=$isecs`
  set subfile = subt.$firstindex.$index.$lmin-$lmax$suff
  echo '#\!/bin/csh' > $subfile
  echo 'setenv PATH' $JSOCROOT'/bin/$JSOC_MACHINE' >> $subfile
  echo 'cd' $PWD >> $subfile
  set interval = '#'$index'/'$indexchunk
  cat parms.tmp | sed s@XXXX@$interval@g | sed s/MMMM/$lmax/g | sed s/NNNN/$lmin/g | sed s/CCCC/$lchunk/g | sed s/TTTT/$timechunk/g | sed s/SSSS/$istart/g > v2t.parms.$index
  echo \(time jv2ts @v2t.parms.$index\) '>&' v2t.log.$index >> $subfile
  echo echo \$status '>&' jv2ts.exitstatus.$index >> $subfile
@ i++
end

@ index += $indexchunk
if ($index < $nextfirstindex) then
@ indexchunk = $nextfirstindex - $index
  set isecs = `echo "$startsecs + ($i * $chunksecs)" | bc`
  set istart = `time_convert o=cal zone=tai s=$isecs`
  set chunksecs = `echo "$indexchunk * $trecstep" | bc`
  set subfile = subt.$firstindex.$index.$lmin-$lmax$suff
  echo '#\!/bin/csh' > $subfile
  echo 'setenv PATH' $JSOCROOT'/bin/$JSOC_MACHINE' >> $subfile
  echo 'cd' $PWD >> $subfile
  set interval = '#'$index'/'$indexchunk
  cat parms.tmp | sed s@XXXX@$interval@g | sed s/MMMM/$lmax/g | sed s/NNNN/$lmin/g | sed s/CCCC/$lchunk/g | sed s/TTTT/$chunksecs's'/g | sed s/SSSS/$istart/g > v2t.parms.$index
  echo \(time jv2ts @v2t.parms.$index\) '>&' v2t.log.$index >> $subfile
  echo echo \$status '>&' jv2ts.exitstatus.$index >> $subfile
@ ntimechunks++
  set chunksecs = `durcon $timechunk`
  set indexchunk = `echo "$chunksecs / $trecstep" | bc`
endif

echo $ntimechunks job scripts created

waittosubmit $jobthreshold subt
set i=0
while ($i < $ntimechunks)
@ index = $firstindex + $i * $indexchunk
  set subfile = subt.$firstindex.$index.$lmin-$lmax$suff
  qsub -q $q -e $qsubtmp -o $qsubtmp $subfile
@ i++
end

echo jobs submitted, start waiting

set njobsrunning = `qstat -r -u $USER | grep "Full jobname:" | grep subt.$firstindex | grep $lmin-$lmax | grep "$suff" | wc -l`
while($njobsrunning > 0)
  sleep 60
  set njobsrunning = `qstat -r -u $USER | grep "Full jobname:" | grep subt.$firstindex | grep $lmin-$lmax | grep "$suff" | wc -l`
end

#check for errors here
set expectedlist = `/bin/ls v2t.parms.[0-9]* | cut -d'.' -f 3`
set ranlist   = `/bin/ls v2t.log.* | cut -d'.' -f 3`
set rerunlist = `echo $expectedlist $ranlist | sed s/" "/"\n"/g | sort -n | uniq -u`

set errlist1 = `grep -Hv 0 jv2ts.exitstatus.* | awk -F '[.:]' '{print $3}'`
set errlist2 = `grep -Hc "successful completion" v2t.log.* | grep -v :1 | awk -F '[.:]' '{print $3}'`
set errlist = `echo $errlist1 $errlist2 | sed s/" "/"\n"/g | sort -n | uniq`

if ($#rerunlist || $#errlist) then
  echo some jobs fail, rerunning
  echo rerunlist: $rerunlist > faillog
  echo errlist1: $errlist1 >> faillog
  echo errlist2: $errlist2 >> faillog
  waittosubmit $jobthreshold subt
  foreach ind ($errlist $rerunlist)
    qsub -q $q -e $qsubtmp -o $qsubtmp subt.$firstindex.$ind.$lmin-$lmax$suff
  end

  set njobsrunning = `qstat -r -u $USER | grep "Full jobname:" | grep subt.$firstindex | grep $lmin-$lmax | grep "$suff" | wc -l`
  while($njobsrunning > 0)
    sleep 60
    set njobsrunning = `qstat -r -u $USER | grep "Full jobname:" | grep subt.$firstindex | grep $lmin-$lmax | grep "$suff" | wc -l`
  end

  set ranlist   = `/bin/ls v2t.log.* | cut -d'.' -f 3`
  set rerunlist = `echo $expectedlist $ranlist | sed s/" "/"\n"/g | sort -n | uniq -u`
  set errlist1 = `grep -Hv 0 jv2ts.exitstatus.* | awk -F '[.:]' '{print $3}'`
  set errlist2 = `grep -Hc "successful completion" v2t.log.* | grep -v :1 | awk -F '[.:]' '{print $3}'`

  if ($#errlist1 || $#errlist2 || $#rerunlist) then
    echo some jobs still fail, i give up
    exit 1
  endif
endif

echo successful completion

rm parms.tmp

exit 0