#! /bin/csh -f

source /home/jsoc/.setJSOCenv
setenv SGE_ROOT  /SGE2
set QUE = k.q
set QSUB = /SGE2/bin/lx-amd64/qsub

set SHOW_INFO = /home/jsoc/cvs/Development/JSOC/bin/$JSOC_MACHINE/show_info
set TIME_CONVERT = /home/jsoc/cvs/Development/JSOC/bin/$JSOC_MACHINE/time_convert
set S = /home/jsoc/cvs/Development/JSOC/bin/linux_avx/stokes_dcon

set lastDC = `$SHOW_INFO hmi.Ic_720s_dconS'[$]' -q key=t_rec | awk -F\_ '{print $1}'`
set lastIC = `$SHOW_INFO hmi.Ic_720s'[$]' -q key=t_rec | awk -F\_ '{print $1}'`
@ lastDC_s = `$TIME_CONVERT time=$lastDC`
@ lastIc_s = `$TIME_CONVERT time=$lastIC`
@ diff = $lastIc_s - $lastDC_s

if ( $diff == 0 ) then
  echo "No new data to process"
  exit
endif

@ next_s = $lastDC_s + 86400
set next = `$TIME_CONVERT s=$next_s zone=TAI | awk -F\_ '{print $1}'`
set wantT = $next'_'19:00_TAI
set day = `echo $wantT | awk -F\_ '{print $1}'`
set TSTMP = `echo $day | awk -F\. '{print $2$3}'`
set CMD = /tmp28/jsocprod/DCON720s/DCS_$TSTMP.cmd
set LOG = /tmp28/jsocprod/DCON720s/DCS_$TSTMP.log
if ( -e $CMD ) then
  rm $CMD
endif
if ( -e $LOG ) then
  rm $LOG
endif
echo "hostname >>&$LOG" >$CMD
echo "set echo >>&$LOG" >>$CMD
echo "setenv OMP_NUM_THREADS 4" >>$CMD

while ( $next_s <= $lastIc_s )
  @ count = `$SHOW_INFO hmi.Ic_720s'['$day'/1d]' -qc`
  if ( $count > 120 ) then
    echo "Bad records need to be deleted"
    exit
  endif
  while ( $count < 117 )
    sleep 300
    @ count = `$SHOW_INFO hmi.Ic_720s'['$day'/1d]' -qc`
  end
  if ( `$SHOW_INFO hmi.Ic_720s'['$wantT'-'$day'_23:59:59_TAI][? quality = 0 ?]' -q n=1 key=t_rec | wc -l` == 1 ) then
    set T = `$SHOW_INFO hmi.Ic_720s'['$wantT'-'$day'_23:59:59_TAI][? quality = 0 ?]' -q n=1 key=t_rec`
    echo $T
  else if ( `$SHOW_INFO hmi.Ic_720s'['$day'_00:00:00_TAI-'$wantT][? quality = 0 ?]' -q n=-1 key=t_rec | wc -l` == 1 ) then
    set T = `$SHOW_INFO hmi.Ic_720s'['$day'_00:00:00_TAI-'$wantT][? quality = 0 ?]' -q n=-1 key=t_rec`
    echo $T
  else
    echo "No good data for $day"
    exit
  endif

  echo "$S in=hmi.S_720s'['$T']' out=hmi.S_720s_dconS psf=hmi.psf " >> $CMD
  echo "/home/jsocprod/for_aimee/daily/modL/make_obsModL.csh $T" >> $CMD

  @ next_s = $next_s + 86400
  set next = `$TIME_CONVERT s=$next_s zone=TAI | awk -F\_ '{print $1}'`
  set wantT = $next'_'19:00_TAI
  set day = `echo $wantT | awk -F\_ '{print $1}'`
end

$QSUB -e $LOG -o $LOG -q $QUE $CMD